GuiXT Tutorial Allgemeines 1 Layout ändern 2 3 4 5 6 weiter

Häufig sind die Bildschirme im R/3-Standard sehr umfangreich und enthalten eine Reihe nicht benötigter Felder. Das erschwert die Orientierung und das Auffinden der tatsächlich relevanten Informationen. Bei der Dateneingabe behindern die unnötigen Felder den effizienten Ablauf, und bei der Einarbeitung neuer Benutzer sind Zusatzerklärungen nötig (“In diesem Feld  nichts eingeben”).

Mit GuiXT können Sie sehr einfach die nicht benötigten Felder löschen und die verbliebenen neu anordnen. Wir zeigen das an einem Beispiel (MM03, Materialstammsatz, Grunddaten 1).  

Im Unterschied zu speziellen Konfigurationsmöglichkeiten innerhalb der SAP-Anwendungen (z.B. für den Materialstammsatz) funktioniert GuiXT  in gleicher Weise für alle Anwendungen und Bildschirmbilder. Mit der Kenntnis weniger Anweisungen (wie del zum Löschen und pos zum Verschieben) können Sie  die Masken lokal an Ihrem PC  neu gestalten und dann nach Abschluss der Entwicklung für grössere Benutzergruppen freigeben.  

 

Sap Guixt image.1.1 Layout ändern 

       Ausgangspunkt: SAP Standardbildschirm in der Materialwirtschaft

 
 

Sap Guixt image.1.2 Layout ändern 

        Rot markiert: die nicht benötigten Felder

Vorgehen: Klicken Sie im GuiXT Fenster auf “Script” . Es wird dann der Editor (Standard: notepad) für die zugeordnete Script-Datei geöffnet. Durch “del” Befehle löschen SIe alle nicht benötigten Elemente. Dabei können Sie die Feldnamen jeweils durch Mausklick im GuiXT Fenster “Screen elements” entnehmen und mit Ctrl+V in dem Skript einfügen:

del F[Ext.Warengrp.]
del F[Werksüb. MatStatus]
del F[Labor/Büro]
del F[allg.Postypengr]
del F[Gültig ab]
del C[Gültigkeit bewerten]
del F[Produkthierar.]
del G[Materialberechtigungsgruppe]
del P[Revisionsstand anzeigen]

del F[Volumen]
del F[Volumeneinheit]
del F[Größe/Abmessung]

GuiXT Fenster “Screen elements”:

Sap Guixt image.1.5 Layout ändern  

 

 

 

 

 

 

 

 

Dabei sind F[...] Einzelfelder, G[...] Feldgruppen mit Rahmen, P[...] Drucktasten (Pushbutton), C[...] Ankreuzfelder (Checkbox). 

Sap Guixt image.1.3 Layout ändern 

     Neue Anordnung der verbliebenen Felder
 
Als nächstes verschieben Sie die verbliebenen Felder mit dem “pos” Befehl, um das gewünschte Layout zu erhalten:
 
// Felder und Feldgruppen verschieben
 
pos F[EAN/UPC-Code] F[Nettogewicht]+(1,0) 
 
pos F[EAN-Typ] F[EAN/UPC-Code]+(0,40) 
 
pos G[Allgemeine Daten] F[Material]+(2,0) 
 
pos G[Abmessungen/EAN] (10,1) 
 
pos G[Verpackungsmaterialdaten] (15,1) 
 
pos G[Grunddatentexte] (18,1)
 
Sie nennen bei “pos” jeweils das Bildschirmelement, wie bei “del”, und dann die neue Position. Entweder mit fixen Koordinaten (Zeile,Spalte), oder relativ zu einem anderen Bildschirmelement. 
 
Für Verkleinerung o
der Vergrösserung der Gruppenrahmen können Sie “BoxSize” benutzen:
 
// Neue Rahmengrössen setzen
 
BoxSize G[Allgemeine Daten] (6,78) 
 
BoxSize G[Abmessungen/EAN] (5,78) 
  BoxSize G[Verpackungsmaterialdaten] (3,78) 

 
BoxSize G[Grunddatentexte] (3,78)

Sap Guixt image.1.4 Layout ändern 

      Fertiges neues Layout

Das neue Layout soll nur für “Grunddaten 1″ gelten. Da das GuiXT-Skript pro Bildschirm (SAP-Dynpro) abgelegt wird, aber nicht für jeden Reiter eines Bildschirms unterschiedlich, benötigen Sie noch eine Abfrage auf den aktiven Reiter “Grunddaten 1″. Insgesamt sieht das Skript damit wie folgt aus: 

// GuiXT Script saplmgmm.d4004.txt
// Materialstamm

if Q[Page=Grunddaten 1]

// Nicht benötigte Felder löschen
del F[Ext.Warengrp.]
del F[Werksüb. MatStatus]
del F[Labor/Büro]
del F[allg.Postypengr]
del F[Gültig ab]
del C[Gültigkeit bewerten]
del F[Produkthierar.]
del G[Materialberechtigungsgruppe]
del P[Revisionsstand anzeigen]

del F[Volumen]
del F[Volumeneinheit]
del F[Größe/Abmessung]

// Felder und Feldgruppen verschieben 
pos F[EAN/UPC-Code] F[Nettogewicht]+(1,0)
pos F[EAN-Typ] F[EAN/UPC-Code]+(0,40)
pos G[Allgemeine Daten] [Material]+(2,0)
pos G[Abmessungen/EAN] (10,1)
pos G[Verpackungsmaterialdaten] (15,1)
pos G[Grunddatentexte] (18,1)

// Neue Rahmengrössen setzen
BoxSize G[Allgemeine Daten] (6,78)
BoxSize G[Abmessungen/EAN] (5,78)
BoxSize G[Verpackungsmaterialdaten] (3,78)
BoxSize G[Grunddatentexte] (3,78)

endif

Falls Sie das neue Layout nur in der Materialanzeige haben möchten (Transaktion MM03), bei “Hinzufügen” oder “Ändern” aber ein davon abweichendes, können Sie das steuern durch

// Abfrage auf Transaktion MM03
if Q[Transaction=MM03]

endif

 

Tip: Statt der direkten Eingabe der Script-Anweisungen können Sie auch mit dem wysiwyg Tool “GuiXT Designer” arbeiten; es generiert die Script-Anweisungen automatisch. Einzelheiten dazu finden Sie in dem Designer-Tutorial.

Sap Guixt weiter Layout ändern

Layout ändern